* Copyright 1975 Stuart D. Gathman
	 ORG $6200 KIM VERSATILE INTERFACE ADAPTER
V1ORB	 RES 1	  OUTPUT REGISTER B
	 RES 1
V1DDRB	 RES 1	  DATA DIRECTION B
V1DDRA	 RES 1	  DATA DIRECTION A
V1T1CL	 RES 1	  WRITE LATCH/READ COUNTER   TIMER 1
V1T1CH	 RES 1	  WRITE LATCH & SET COUNTER/READ COUNTER
V1T1LL	 RES 1	  TIMER 1 LATCH LOW
V1T1LH	 RES 1	  TIMER 1 LATCH HIGH
	 RES 1
	 RES 1
	 RES 1
V1ACR	 RES 1	  AUX CONTROL REGISTER
	 RES 1
V1IFR	 RES 1	  INTERRUPT FLAG REGISTER
V1IER	 RES 1	  INTERRUPT ENABLE REGISTER
V1ORA	 RES 1	  OUTPUT A WITHOUT HANDSHAKE
*
NLINES	 EQU 4	  NUMBER OF RS232 LINES
RLINES	 EQU 1	  NUMBER OF LINES INSTALLED
ASIZ	 EQU 22   SIZE OF AUTO ANSWER BACK BUFFER
TBASE	 EQU 1111 TIME BASE CONSTANT (CYCLES/TIC)
*
* SETUP BYTE BIT MASKS
EVEN	 EQU 80H  EVEN PARITY SETUP BITS
ODD	 EQU 81H  ODD PARITY SETUP BITS
STP1	 EQU 04H  ONE STOP BIT SETUP
STP2	 EQU 00H  TWO STOP BITS SETUP
NONE	 EQU 00H  NO PARITY SETUP
*
*  LINE MONITOR FLAG BYTE  (1ST 6 DISPLAYED IN STATUS LIGHTS)
RCVD	 EQU 01H  RECEIVE BUFFER FULL
XMIT	 EQU 02H  TRANSMIT BUFFER BULL
OVRN	 EQU 04H  OVERRUN ERROR
FERR	 EQU 08H  FRAMING ERROR
PERR	 EQU 10H  PARITY ERROR
CONN	 EQU 20H  CONNECT/DISCONNECT STATUS OF RECEIVE LINE
RCON	 EQU 40H  REQUEST CONNECT/DISCONNECT FOR XMIT LINE
INTR	 EQU 80H  INTERRUPT - CONNECT/DISCONNECT
*
* DISPATCHER FLAGS
XOFF	 EQU 01H  XOFF CHARACTER SENT
PAU	 EQU 02H  PAUSE REQUESTED
FULL	 EQU 04H  INPUT BUFFER FULL
EMPTY	 EQU 08H  OUTPUT BUFFER EMPTY
SUPR	 EQU 20H  SUPPRESS INCOMING DATA
DPND	 EQU 80H  DISCONNECT PENDING
*
ETX	 EQU 03H  DISCONNECT CHARACTER
ENQ	 EQU 05H  ENQUIRY CHARACTER
CR	 EQU 0DH  CARRIAGE RETURN
*
	 ORG 0	  PAGE ZERO
*
* LINE MONITOR REGISTERS
FLAGS	 RES NLINES	   COMMUNICATION FLAGS
IBUF	 RES NLINES	   CHARACTER WORK REGISTER
ICHAR	 RES NLINES	   CHARACTER BUFFER
IWRK	 RES NLINES	   PARITY WORK REGISTER
OBUF	 RES NLINES	   OUTPUT CHARACTER BUFFER
OCHAR	 RES NLINES	   OUTPUT CHARACTER
OWRK	 RES NLINES	   OUTPUT WORK REGISTER
IOBITS	 RES 1		   USED TO STROBE INPUT LINES
SAVX	 RES 1
IRQX	 RES 1
IRQY	 RES 1
LINENO	 RES 1
PCL	 RES NLINES*2	   PC LOW
PCH	 RES NLINES*2	   PC HIGH
DELAY	 RES NLINES*2	   DELAY IN TICS
SAVY	 RES NLINES*2	   SAVE Y REG FOR COUNT, ETC.
*
* DISPATCHER WORK AREA
DFLGS	 RES NLINES	DISPATCH/NONDISPATCH FLAGS
TEMP	 RES 1		TEMPORARY SAVE AREA
PTRL	 RES 1		BUFFER POINTER LOW
PTRH	 RES 1		BUFFER POINTER HIGH
OPTRL	 RES 1		OUTPUT BUFFER POINTER
OPTRH	 RES 1
IPTRL	 RES 1		INPUT BUFFER POINTER
IPTRH	 RES 1
APTRL	 RES 1
APTRH	 RES 1
TMPY	 RES 1
TMPX	 RES 1
SAVO	 RES 1
SAVI	 RES 1
MODE	 RES 1
OTOP	 RES NLINES	TOP POSITION
OBOT	 RES NLINES	BOTTOM POSITION OF OUTPUT BUFFER
ITOP	 RES NLINES	INPUT TOP
IBOT	 RES NLINES	INPUT BOTTOM
IFIG	 RES NLINES	CASE FLAG FOR INPUT
OFIG	 RES NLINES	CASE FLAG FOR OUTPUT
BCNT	 RES NLINES	INPUT BUFFER COUNT
ANSBC	 RES NLINES	STOP COUNT FOR AUTO ANSWER BACK
WCNT	 RES NLINES	START COUNT FOR AUTO ANSWER BACK
ANSB1	 RES ASIZ	ANSWER BACK BUFFERS
ANSB2	 RES ASIZ
ANSB3	 RES ASIZ
*
* BUFFER ALLOCATIONS
	 ORG $0100	USE PART OF STACK
IBUF0	 RES 128	FOR S/1 BUFFER
OBUF0	 RES 42		LEAVING TOP OF STACK FOR PROGRAM
	 ORG $0200
IBUF1	 RES 128
IBUF2	 RES 128
IBUF3	 RES 128
OBUF1	 RES 42
OBUF2	 RES 42
OBUF3	 RES 42
*
	 ORG $4000	EPROM MEMORY  (KIM RAM FOR TEST)
BIT3	 BYTE 1,6,6,6	1/3 BIT TIMES FOR LINES
BIT	 BYTE 3,18,18,18    BIT TIME FOR LINES
CHLEN	 BYTE 7,5,5,5	CHAR LEN (NOT INCLUDING START,STOP,PARITY)
PARITY	 BYTE EVEN+STP2,NONE+STP1,NONE+STP1,NONE+STP1
OBUFL	 BYTE >OBUF0,>OBUF1,>OBUF2,>OBUF3
OBUFH	 BYTE <OBUF0,<OBUF1,<OBUF2,<OBUF3
OSIZE	 BYTE 41,41,41,41
IBUFL	 BYTE >IBUF0,>IBUF1,>IBUF2,>IBUF3
IBUFH	 BYTE <IBUF0,<IBUF1,<IBUF2,<IBUF3
ISIZE	 BYTE 127,127,127,127
ANSBL	 BYTE >ANSB1,>ANSB2,>ANSB3
ANSBH	 BYTE <ANSB1,<ANSB2,<ANSB3
XMAX	 BYTE 96,$FF,$FF,$FF	     XOFF TRIGGER
XMIN	 BYTE 32,$FF,$FF,$FF	      XON TRIGGER
*
IRQ	 PHA
	 LDA V1IFR
	 BMI TIMER1
RETI	 PLA
IGNORE	 RTI
*
TIMER1	 STA V1IFR   RESET FLAGS
	 ASL A
	 BPL RETI
*
* SIMULATE A BUNCH OF ACIA'S
	 STX IRQX
	 STY IRQY
	 LDA V1ORB	    CHECK PORT SELECT FOR STATUS DISPLAY
	 AND #3
	 TAX
	 LDA FLAGS,X	    GET STATUS
	 ASL A
	 ASL A
	 STA V1ORB	    UPDATE STATUS DISPLAY
*
	 LDA IOBITS
	 EOR #$FF	    TRANSISTORS REVERSE SERIAL I/O
	 STA V1ORA	    STROBE OUTPUT LINES
	 LDA V1ORA	    STROBE INPUT LINES
	 EOR #$FF
	 STA IOBITS
*
	 LDA #NLINES-1
	 STA LINENO
	 LDX #0
CHECK	 JSR SWITCH	    GET OUTPUT BIT
	 ROL IOBITS	    SAVE OUT BIT AND GET INBIT
	 JSR SWITCH	    PROCESS INPUT BIT
	 DEC LINENO	    PROCESS NEXT LINE
	 BPL CHECK
*
	 LDY IRQY
	 LDX IRQX
	 PLA
	 RTI
*
SWITCH	 DEC DELAY,X  ** EXECUTE LINE MONITOR
	 BNE SKPDLY
	 LDA PCH,X
	 PHA
	 LDA PCL,X
	 PHA
LINE	 EQU *		 SETUP TO CALL LINE MONITOR
	 STX SAVX
	 LDY SAVY,X
	 LDX LINENO
SKPDLY	 RTS
WAITBIT  LDA BIT,X
WAIT	 LDX SAVX     ** RETURN TO CALLER
	 STY SAVY,X
	 STA DELAY,X
	 PLA
	 STA PCL,X
	 PLA
	 STA PCH,X
	 INX
	 RTS
*
OUTDROP  LDY #150      HOLD SPACE FOR 3 SECS TO DISCONNECT
ODWT	 CLC
	 JSR WAITBIT
	 DEY
	 BNE ODWT
OUTIDLE  CLC
OUTWAIT  JSR WAITBIT
	 LDA FLAGS,X
	 ASL A	       CHECK REQUEST CONNECT
	 BPL OUTIDLE
	 ASL A	       CHECK CONNECT
	 SEC		 BRING UP MARK AS PER REQUEST
	 BPL OUTWAIT
*
OUTLINE  SEC	       MAINTAIN MARK
	 JSR WAITBIT
	 LDA FLAGS,X
	 AND #XMIT+RCON
	 EOR #XMIT+RCON
	 BEQ OUTLINE	  WAIT FOR LINE DROP OR CHAR TO SEND
	 AND #RCON
	 BNE OUTDROP   DISCONNECT AS PER REQUEST
*
	 LDA FLAGS,X
	 ORA #XMIT	INTERRUPT - TRANSMIT BUFFER EMPTY
	 STA FLAGS,X
	 LDA OCHAR,X
	 STA OBUF,X
	 LDY CHLEN,X	COUNT OF BITS IN CHAR
	 ASL OWRK,X	INITIALIZE PARITY
	 CLC		GENERATE START BIT
	 JSR WAITBIT
OLOOP	 LDA OWRK,X
	 EOR OBUF,X	COMPUTE PARITY
	 STA OWRK,X
	 LSR OBUF,X	GET NEXT BIT
	 JSR WAITBIT
	 DEY
	 BNE OLOOP
	 LDA PARITY,X	CHECK FOR PARITY
	 BPL STOPBIT
	 EOR OWRK,X
	 LSR A		PARITY INTO CARRY
	 JSR WAITBIT	OUTPUT PARITY BIT
STOPBIT  LDA PARITY,X
	 AND #STP1	CHECK 1 OR TWO STOP BITS
	 BNE OUTLINE	ONLY ONE STOP BIT
	 SEC
	 JSR WAITBIT
	 JMP OUTLINE	GO SEND SECOND STOP BIT
*
NOSTOP	 ORA #FERR
	 STA FLAGS,X
	 LDY #100
FLOOP	 JSR WAITBIT	 BREAK TIME OUT
	 BCS FRAME     STORE CHAR IF MARK BACK UP
	 DEY
	 BNE FLOOP     WAIT FOR MARK
	 LDA FLAGS,X
	 ORA #INTR
INDISC	 AND #-(CONN+RCON)-1  REQUEST AND FLAG DISCONNECT
	 STA FLAGS,X
INIDLE	 JSR WAITBIT
	 BCC INIDLE    WAIT FOR MARK
	 LDA FLAGS,X
	 ORA #RCON
	 STA FLAGS,X   REQUEST CONNECT
	 LDY #5
CONNLP	 JSR WAITBIT
	 LDA FLAGS,X
	 BCC INDISC    CHECK IF MARK UP AT LEAST 5 BITS
	 DEY
	 BNE CONNLP
	 ORA #INTR+CONN  FLAG CONNECTION
CWAIT1	 STA FLAGS,X
CWAIT	 LDA BIT3,X    GET 1/3 BIT TIME
	 JSR WAIT
	 BCS CWAIT     WAIT FOR START BIT
	 LDA BIT3,X
	 JSR WAIT      WAIT FOR CENTER OF PULSES
	 BCS CWAIT     IGNORE SPACE < 1/3 TO 2/3 BIT TIME
	 LDY CHLEN,X   GET CHARACTER LENGTH
CLOOP	 ROL IBUF,X   ROTATE IN BIT
	 JSR WAITBIT
	 DEY
	 BPL CLOOP
*		       STOP/PARITY IS IN CARRY
	 LDA PARITY,X
	 BPL CHKSTP
	 ROL IWRK,X    SAVE PARITY
	 JSR WAITBIT   GET STOP BIT
CHKSTP	 EQU *
	 LDA FLAGS,X
	 AND #-(PERR+FERR+OVRN)-1
	 BCC NOSTOP    NO STOP BIT
	 STA FLAGS,X
FRAME	 LDA #0
	 STA ICHAR,X
	 LDY CHLEN,X
	 LDA IWRK,X
	 EOR PARITY,X
RLOOP	 LSR IBUF,X    REVERSE BITS AND STORE CHARACTER
	 ROL ICHAR,X
	 EOR ICHAR,X
	 DEY
	 BNE RLOOP
	 LSR A	       PARITY ERROR IF CARRY SET
	 LDA FLAGS,X
	 BCC NOPERR
	 ORA #PERR
NOPERR	 ROR FLAGS,X   CHECK RCV DATA
	 BCC SKPOVR
	 ORA #OVRN     SET OVERRUN ERROR
SKPOVR	 ORA #RCVD     FLAG RCVD CHAR + INTERRUPT
	 BNE CWAIT1
*
RESET	 LDX #$FF
	 TXS		INITIALIZE STACK
	 CLD		CLEAR DECIMAL MODE
	 LDA #$7F
	 STA V1IER	DISABLE ALL INTERRUPTS ON VIA
	 LDA #$0F
	 STA V1DDRA	4 INPUTS / 4 OUTPUTS ON PORT A (SERIAL TTL)
	 LDA #$FC
	 STA V1DDRB	PORT B, SIX OUT - TWO IN (STATUS DISPLAY)
	 LDA #$40
	 STA V1ACR	SET TIMER1 TO FREE RUNNING MODE
	 LDA #>TBASE
	 STA V1T1CL	TIMER LATCH - LOW BYTE
	 LDA #<TBASE
	 STA V1T1CH		    - HIGH BYTE, START COUNTER
	 LDA #$C0
	 STA V1IER	ENABLE TIMER INTERRUPT
	 LDA #0
	 STA V1ORA	INITIALIZE OUTPUT LINES TO SPACE
*
	 LDA #NLINES-1
	 STA LINENO
	 LDX #0
INITLP	 JSR LINE	CALCULATE LINE #
	 LDA #XMIT
	 STA FLAGS,X	INITIALIZE FLAGS
	 LDA #EMPTY
	 STA DFLGS,X	INITIALIZE DISPATCH FLAGS
	 LDA #0
	 STA OTOP,X	INITIALIZE BUFFERS
	 STA OBOT,X
	 STA ITOP,X
	 STA IBOT,X
	 STA BCNT,X
	 LDA #ASIZ-1	INITIALIZE ANSWERBACK BUFFERS
	 STA ANSBC,X
	 STA WCNT,X
	 JSR OUTIDLE	START OUTPUT MONITOR
	 JSR LINE
	 JSR INIDLE    START INPUT MONITOR
	 DEC LINENO
	 BPL INITLP
	 CLI		START LINE MONITORS RUNNING
*
MAIN	 LDX #0
	 JSR OUTINIT	START OUTPUT TO S/1
	 LDA #'G'
	 JSR OUT
	 LDA #RLINES+$30  OUTPUT NO. LINES INSTALLED FOR S/1
	 JSR OUT
	 LDA #CR
	 JSR OUT
	 LDA #0
	 STA IBOT	CLEAR INPUT BUFFER
	 STA ITOP
	 STA BCNT
	 LDA DFLGS
	 AND #-(SUPR+FULL)-1  ENABLE INPUT
	 STA DFLGS
	 JSR ININIT	START INPUT FROM S/1
SNXT	 JSR IN
	 CMP #'G'
	 BEQ S1OUT
	 CMP #'1'
	 BCC SNXT
	 AND #3		ASSUME DIGIT & CONVERT TO INDEX
	 BEQ MAIN	ERROR
	 TAX
	 JSR OUTINIT
	 JSR IN
	 CMP #'D'
	 BEQ DODISC
	 CMP #'W'
	 BEQ DOWRU
	 CMP #'C'
	 BNE MAIN
OUTLP	 JSR IN
	 CMP #CR
	 BEQ SNXT
	 JSR OUT
	 JMP OUTLP
DODISC	 JSR FINDEND
	 LDA DFLGS,X
	 ORA #DPND	  FLAG DISCONNECT PENDING
	 STA DFLGS,X
	 JMP SNXT
DOWRU	 LDA ANSBL-1,X
	 STA APTRL
	 LDA ANSBH-1,X
	 STA APTRH
	 LDY #ASIZ-1
WRULP	 JSR IN
	 CMP #CR
	 BEQ WRUDN
	 STA (APTRL),Y
	 DEY
	 BPL WRULP
	 JSR FINDEND
WRUDN	 STY ANSBC,X
	 STY WCNT,X
	 JMP SNXT
*
S1OUT	 LDA DFLGS
	 ORA #SUPR
	 STA DFLGS	SUPPRESS ECHO FROM S/1
	 LDX #0
	 JSR OUTINIT	START OUTPUT TO S/1
	 LDX #RLINES
LLP	 JSR ININIT
	 LDY BCNT,X	GET NO. CHARS TO PROCESS
SMODE	 LDA #0
	 STA MODE
INLP	 DEY
	 BMI LNXT
	 JSR IN
	 CMP #ETX
	 BEQ SNDISC
	 CMP #ENQ
	 BEQ SNDENQ
	 PHA
	 LDA #'C'	SEND CONNECT LINE
	 JSR SETMODE
	 PLA
	 PHA
	 JSR OUT
	 PLA
	 CMP #'='
	 BNE INLP
	 LDA #CR
	 JSR OUT
	 JMP SMODE
SNDISC	 LDA #'D'
SNDSTAT  JSR SETMODE
	 JMP INLP
SNDENQ	 LDA #'W'
	 BNE SNDSTAT
	 JMP INLP
*
LNXT	 LDY #'C'
	 LDA FLAGS,X
	 AND #CONN
	 BNE L1
	 INY
L1	 TYA
	 JSR SETMODE
	 LDA #CR
	 JSR OUT
	 DEX
	 BNE LLP
MAINV	 JMP MAIN
*
SETMODE  CMP MODE    PREPARE PROTOCOL EVIRONMENT IN A
	 BEQ SM1
	 PHA
	 LDA MODE
	 BEQ SM2
	 LDA #CR
	 JSR OUT
SM2	 TXA	     GET INDEX
	 ORA #$30    MAKE A DIGIT
	 JSR OUT
	 PLA
	 JSR OUT
SM1	 RTS
*
FINDEND  JSR IN
	 CMP #CR
	 BNE FINDEND
	 RTS
*
ININIT	 STX SAVI
	 LDY IBUFL,X
	 STY IPTRL
	 LDY IBUFH,X
	 STY IPTRH
	 RTS
IN	 STY TMPY
	 STX TMPX
CKIN	 JSR CKLINES
	 LDX SAVI
	 LDA BCNT,X	CHECK INPUT CNT
	 BEQ CKIN	WAIT IF EMPTY
	 CMP XMIN,X
	 BNE I2
	 LDA DFLGS,X
	 AND #-PAU-1
	 STA DFLGS,X
I2	 LDY IBOT,X
	 LDA (IPTRL),Y
	 DEY
	 BPL I1
	 LDY ISIZE,X
I1	 STY IBOT,X
	 DEC BCNT,X
	 LDY TMPY
	 LDX TMPX
	 RTS
*
OUTINIT  LDY OBUFL,X	SET OUTPUT BUFFER POINTER TO X
	 STY OPTRL
	 LDY OBUFH,X
	 STY OPTRH
	 STX SAVO
	 RTS
OUTCH	 PHA		OUTPUT A CHARACTER, NO REGS SAVED
CKOUT	 JSR CKLINES
	 LDX SAVO
	 LDA DFLGS,X
	 AND #DPND     CHECK FOR PENDING DISCONNECT
	 BEQ CKOUT
	 LDA OTOP,X
	 CMP OBOT,X
	 BNE OUTOK
	 LDA DFLGS,X
	 AND #EMPTY
	 BEQ CKOUT	IF NOT EMPTY, MUST BE FULL
	 SEI
	 LDA FLAGS,X
	 ORA #RCON
	 STA FLAGS,X
	 CLI
OUTOK	 PLA
	 LDY OTOP,X
	 STA (OPTRL),Y
	 DEY
	 BPL O1
	 LDY OSIZE,X
O1	 STY OTOP,X
	 RTS
*
CKLINES  EQU *		CHECK LINE MONITORS, NO REGS SAVED
	 LDX #RLINES
DRET	 SEI
DLOOP	 LDA FLAGS,X	CHECK FOR INTERRUPT
	 BPL NOCONN	CHECK FOR CONNECT/DISCONNECT
	 AND #-INTR-1	RESET INTERRUPT
	 STA FLAGS,X
	 CLI
	 AND #CONN
	 BNE CONNECT
	 LDA DFLGS,X
	 AND #FULL
	 BNE DRET
	 LDA #ETX
	 JSR NOXLATE	BUFFER ETX CHAR TO SIGNAL DISCONNECT
	 LDA OTOP,X
	 STA OBOT,X	CLEAR OUTPUT BUFFER
	 LDA ANSBC,X
	 STA WCNT,X	RESET ANSWER BACK COUNT
	 LDA DFLGS,X
	 ORA #EMPTY	CLEAR OUTPUT BUFFER
	 STA DFLGS,X
	 BNE DRET
*
CONNECT  LDA #$7F	INITIALIZE CASE FLAGS
	 STA OFIG,X
	 LDA #0
	 STA IFIG,X
	 BEQ DRET
*
NOCONN	 LSR A		CHECK RECEIVE BIT
	 BCC NORECV
	 ASL A		PUT BITS BACK AND CLEAR RECEIVE
	 STA FLAGS,X
	 LDA DFLGS,X
	 AND #FULL+SUPR CHECK IF BUFFER FULL OR SUPRESS INPUT
	 BEQ INOK
	 AND #SUPR
	 BNE DLOOP	IGNORE IF INPUT SUPPRESSED
DISC	 LDA FLAGS,X
	 AND #-RCON-1	REQUEST DISCONNECT IF BUFFER FULL
	 STA FLAGS,X
	 JMP DNXT
INOK	 LDA ICHAR,X	GET CHARACTER
	 CLI		RESTART INTERRUPTS BEFORE PROCESSING
	 JSR INCHAR	TRANSLATE AND STORE IN BUFFER
	 JMP DRET	CONTINUE
*
T1	 LDA DFLGS,X
	 AND #EMPTY
	 BNE PENDING	CHECK PENDING DISCONNECT IF BUFFER EMPTY
	 JSR BUFOUT
TRANSMIT SEI
	 LDA FLAGS,X
	 AND #-XMIT-1
	 STA FLAGS,X
*
DNXT	 DEX
	 BPL DLOOP
	 CLI
	 RTS
*
NORECV	 LSR A		CHECK TRANSMIT BIT
	 BCC DNXT
	 CLI
	 LDA DFLGS,X	CHECK DISPATCH FLAGS
	 AND #PAU+XOFF
	 BEQ CKWRU	CONTINUE IF NO HANDSHAKE
	 EOR #PAU+XOFF
	 BEQ CKWRU	 SAME AS ABOVE
	 ORA #16	MAKE XON/XOFF
	 STA OCHAR,X
	 LDA DFLGS,X
	 EOR #XOFF
	 STA DFLGS,X
	 JMP TRANSMIT
*
PENDING  LDA DFLGS,X	CHECK DISCONNECT PENDING
	 SEI
	 BPL DNXT
	 AND #$7F	RESET PENDING DISCONNECT
	 STA DFLGS,X
	 JMP DISC	DISCONNECT LINE
*
CKWRU	 LDA WCNT,X
	 CMP ANSBC,X
	 BEQ T1
	 TAY
	 LDA ANSBL-1,X
	 STA PTRL
	 LDA ANSBH-1,X
	 STA PTRH
	 LDA (PTRL),Y
	 STA OCHAR,X
	 DEY
	 STY WCNT,X
	 JMP TRANSMIT
*
BUFOUT	 LDY OBUFL,X	TRANSFER CHAR FROM OUT BUFFER TO OCHAR
	 STY PTRL
	 LDY OBUFH,X
	 STY PTRH
	 LDY OBOT,X
	 LDA (PTRL),Y
	 DEY
	 BPL BOTO
	 LDY OSIZE,X
BOTO	 STA OCHAR,X
	 STY OBOT,X
	 TYA
	 CMP OTOP,X	CHECK FOR BUFFER EMPTY
	 BNE BUF1
	 LDA DFLGS,X
	 ORA #EMPTY
	 STA DFLGS,X
BUF1	 RTS
*
OUT	 STA TEMP      OUTPUT ASCII, X&Y SAVED
	 TYA
	 PHA
	 STX TMPX
	 LDX SAVO      GET OUTPUT LINE
	 LDA TEMP
	 CPX #0
	 BEQ OUTNOX    OUTPUT UNTRANSLATED FOR LINE 0
	 CMP #$60
	 BCC UPPER
	 SBC #$20      CONVERT TO UPPER CASE
UPPER	 CMP #$10      CHECK UNRECOGNIZED CONTROL RANGE
	 BCC OKCTL
	 CMP #$20
	 BCC BAUQ      IGNORE UNRECOGNIZED CONTROL CHARACTERS
	 SBC #$10      COMPRESS XLATE TABLE
OKCTL	 TAY
	 LDA BAUDOT,Y
	 STA TEMP
	 ASL A
	 BCS EXPND     GO DO EXPANSION
	 ASL A
	 BCS NOSHFT    SKIP IF CASE-LESS CHAR
	 EOR OFIG,X    CHECK CASE
	 BPL BAU1
	 LDA OFIG,X
	 EOR #84       REVERSE CASE
	 STA OFIG,X
	 JSR OUT       OUTPUT LET/FIG
BAU1	 LDA TEMP
OUTNOX	 JSR OUT       OUTPUT CHAR
BAUQ	 LDX TMPX
	 PLA
	 TAY
	 RTS
*
NOSHFT	 BMI BAU1      OUTPUT - NO CASE
	 BPL BAUQ      IGNORE CHAR
*
EXPND	 LSR A	       INDEX EXPANSION TABLE
	 TAY
EXP2	 LDA EXP,Y
	 BEQ BAUQ      QUIT AT ZERO
	 JSR OUT
	 INY
	 BNE EXP2
*
*
BAUDOT	 EQU *	  ASCII TO BAUDOT XLATE TABLE
*		  BIT 7 = SPECIAL EXPANSION  BITS 0-6 = OFFSET
*		  BIT 5&6 = CHARACTER TYPE
*			0 = LETTER SHIFT
*			1 = FIGURE SHIFT
*			2 = ELIMINATE
*			3 = ANY SHIFT
*
*	0   1	2   3	4   5	6   7	8   9	A   B	C   D	E   F
 BYTE $60,$68,$62,$40,$40,$29,$40,$2B,$40,$40,$62,$40,$40,$68,$40,$40 0
 BYTE $64,$3C,$31,$34,$2D,$80,$3A,$25,$2F,$32,$3D,$31,$2C,$23,$3C,$3D 2
 BYTE $36,$37,$33,$21,$2A,$30,$35,$27,$26,$38,$2E,$3E,$2F,$8B,$32,$39 3
 BYTE $86,$03,$19,$0E,$09,$01,$0D,$1A,$14,$06,$0B,$0F,$12,$1C,$0C,$18 4
 BYTE $16,$17,$0A,$05,$10,$07,$1E,$13,$1D,$15,$11,$2F,$3D,$32,$3D,$3D 5
*
EXP	 BYTE ' 0/0 ',0,' AT ',0,' EQ ',0  ** SPECIAL EXPANSIONS
*
INCHAR	 CPX #0		XLATE AND BUFFER CHARACTER
	 BEQ NOXLATE
	 ASL A		MULT X 2 (CLR CY)
	 ADC IFIG,X	ADD CASE
	 TAY
	 LDA ASCII,Y	GET ASCII CHAR
	 BMI SHIFT	GO DO LET/FIG SHIFT
	 CMP #ENQ
	 BNE NOXLATE
	 LDA #ASIZ-1
	 STA WCNT,X	 START AUTO ANSWER BACK
NOXLATE  LDY IBUFL,X
	 STY PTRL
	 LDY IBUFH,X
	 STY PTRH
	 LDY ITOP,X
	 STA (PTRL),Y	 PUT CHAR IN BUFFER
	 DEY
	 BPL TOP1
	 LDY ISIZE,X
TOP1	 STY ITOP,X
	 INC BCNT,X
	 TYA
	 CMP IBOT,X
	 BNE C1
	 LDA DFLGS,X
	 ORA #FULL	INPUT BUFFER IS FULL
	 STA DFLGS,X
C1	 LDA BCNT,X
	 CMP XMAX,X
	 BNE C3
	 LDA DFLGS,X
	 ORA #PAU	REQUEST XOFF PAUSE
	 STA DFLGS,X
C3	 RTS
SHIFT	 AND #1
	 STA IFIG,X	STORE NEW CASE
	 RTS		TASK COMPLETE
*
ASCII	 EQU *	  BAUDOT TO ASCII
*	 0	 1	 2	 3	 4	 5	 6	 7
*     LTR FIG LTR FIG LTR FIG LTR FIG LTR FIG LTR FIG LTR FIG LTR FIG
 BYTE $00,$00,'E','3','=','=','A','-',' ',' ','S',$27,'I','8','U','7' 0
 BYTE '<','<','D',ENQ,'R','4','J','!','N',',','F','$','C',':','K','(' 1
 BYTE 'T','5','Z','+','L',')','W','2','H','#','Y','6','P','0','Q','1' 2
 BYTE 'O','9','B','?','G','&',$81,$81,'M','.','X','/','V',';',$80,$80 3
*
	 ORG $FFFA
	 WORD IGNORE,RESET,IRQ
*
	 END